本記事では,数値積分の手法の1つであるシンプソンの公式による方法をVBAで実装してみました. 数値積分については他にもいろんな方が記事を書いているのでここでは説明を省略したいと思います.
関数f(x)のaからbまでの積分はシンプソンの公式(または,シンプソン法)を使うと次式のように表されます.
これでもいいのですが,ざっくりしすぎな気もしますね. 数値積分などをするときは積分の計算結果をできるだけ正しく得たいため,積分区間を細かく分割することが多いです. 例えば,p1からp7の積分を6つに分けて考えてみましょう. ちなみに図中の記号(x1,x2,D)は無視しておいてください.
これにシンプソン公式を当てはめると次式になります.
いま分割幅は一定とすると,
となる.ここで,
とおくと,
このようなおかしな表記をしている理由は,プログラムで実際に計算するときの考え方に合わせているためです. ここでは,この式を「式S」と呼ぶことにします.
では,実際にプログラムを見てみましょう.
プログラムは以下の通りです. 後ほど説明するので今は読み飛ばして構いません.
Option Explicit
Function FNE(ByRef θ As Double)
'引数(角度θ(rad))が与えられるとsinθの値を返す関数
FNE = Sin(θ)
End Function
Sub NumericalIntegration()
'最終更新日:2021/2/15
'シンプソンの公式を使ってsinθの積分を数値解析的に求めるプログラム
'積分区間[A1,B1]をND個に分割した小区間にそれぞれシンプソン公式を当てはめる
'*********************変数の定義*********************
Dim i As Integer 'カウンタ
Dim A1 As Double '積分区間[A1,B1]の左端
Dim B1 As Double '積分区間[A1,B1]の右端
Dim ND As Integer '積分区間の分割数
Dim x1 As Double 'シンプソン公式第二項の独立変数
Dim x2 As Double 'シンプソン公式第三項の独立変数
Dim S As Double '数値積分の計算結果
Dim D As Double '分割幅の1/2
'*********************シンプソン公式による数値積分*********************
'積分区間を定義
A1 = 0 '単位:°
B1 = 180 '単位:°
'積分区間の単位を°からradに変換
A1 = 2 * 4 * Atn(1) / 360 * A1
B1 = 2 * 4 * Atn(1) / 360 * B1
'分割数をテキトーに設定
ND = 500
D = (B1 - A1) / (2 * ND) '分割幅の1/2
x1 = A1 + D '当該小区間の中央に相当する独立変数の値
x2 = x1 + D '当該小区間の右端に相当する独立変数の値
S = 0 '初期化
For i = 1 To ND - 1
S = S + 4 * FNE(x1) + 2 * FNE(x2)
x1 = x2 + D
x2 = x1 + D
Next i
S = S + 4 * FNE(x1)
S = S + FNE(A1) + FNE(B1)
S = S * (D / 6 * 2)
Debug.Print "シンプソン公式による積分値:"; S
End Sub
プログラムの核になるのは以下の部分です. まずはこの部分と変数の定義のところだけを見てください.
D = (B1 - A1) / (2 * ND) '分割幅の1/2
x1 = A1 + D '当該小区間の中央に相当する独立変数の値
x2 = x1 + D '当該小区間の右端に相当する独立変数の値
S = 0 '初期化
For i = 1 To ND - 1
S = S + 4 * FNE(x1) + 2 * FNE(x2)
x1 = x2 + D
x2 = x1 + D
Next i
S = S + 4 * FNE(x1)
S = S + FNE(A1) + FNE(B1)
S = S * (D / 6 * 2)
はじめに,小区間p1〜p2について考えます. 分割幅の1/2を表す変数D,当該小区間の中央に相当する独立変数の値x1,当該小区間の右端に相当する独立変数の値x2を図に表すと以下の図のようになります. なお,積分区間[A1,B1]=[p1,p7]です.分割数NDは6となります.
つまり,
for分では,下図のようにx1とx2を1小区間ずつずらしながら式Sの第1項〜第5項に相当する計算をします. 図はfor文のカウンタiが2のときを表しています.
そしてfor分の次の文は式Sの第6項を,さらに次の文は式Sの第7項,第8項を表しています.
最後に次に示す文が,式Sの両辺にdをかけることを表しておりプログラム中の変数Sが積分値になります.
S = S * (D / 6 * 2)
さて,実は今回紹介したプログラムはsin θをθ =0°〜180°まで積分するプログラムになっています. 分割数はテキトーに500としました. ちなみに,解析解は2になります.
プログラムの計算結果は2.00000000000111ぐらいになると思います. ちなみにシンプソン公式をそのまま適用すると(小区間に分割しない),計算結果は2π/3になります.
分割することでより正確になることが確認できますね. ただし,分割数を上げれば必ずしもいい結果が得られるとは限らないので注意してください(分割数を上げすぎると計算過程で数値を丸めるときの誤差によりむしろ精度が悪くなることがある).
最後までお付き合いいただきありがとうございました.
今回はいつもと趣向が違う記事でしたが,今後も農業農村工学(水文学,かんがい排水,土壌物理学,水理学)を中心に記事を執筆していきたいと思います. リクエスト等も受け付けておりますので,ご遠慮なく連絡ください. Twitterアカウント:エビぐんかん@6LxAi9GCOmRigUI メール:nnCreatorCircle@gmail.com
(1) 河村三郎:土木工学プログラム集1 水文・水理1 実用プログラムとグラフィック表示,森北出版,1984,pp.6-11. (2) Keiji Harada:「数値積分法」 (3) 重田出:数値積分と数値微分(基礎)